lzRichEdit in MySQL speichern [gelöst]

[AlterMann]

Hallo

Ich müßte formatierten Text (fett, evtl. kursiv, Zeilenumbrüche) in eine MySQL-DB speichern.

Ich habe im Netz dazu dieses Codestück gefunden:

Code: Alles auswählen

function TForm20.RichText(re: TlzRichEdit): String;
var
   ss: TStringStream;
begin
   ss := TStringStream.Create ('');
   try
     re.Lines.SaveToStream(ss);
     Result := ss.DataString;
   finally
     ss.Free;
   end;
end;
 

Wenn ich diesen Text in ein Textfeld speichere und anschließend wieder einlese und dem lzRichEdit.Text übergebe sind zwar die Zeilenumbrüche noch da, aber die restlichen Formatierungen (fett u. dgl.) sind weg.

Kann mir jemand sagen was ich falsch mache?

Gute Nacht
Christian

[wp_xyz]

Hab das lzRichEdit nicht auf der Maschine, aber das Property Lines scheint mir eher für die Übergabe des unformatierten Texts zu sein. Gibt es vielleicht auch eine "RichText"-Eigenschaft, o.ä, der du den String zuweisen kannst. Oder lies den String über LoadFromStream ein, wobei der Stream zuvor das DB-Feld ausgelesen hat (Beliebter Fehler: nach dem Einlesen des DB-Feldes den Stream wieder an den Anfang zurücksetzen bevor er ans RichEdit übertragen wird).

[theo]

Kann mir jemand sagen was ich falsch mache?

Warum machst du
re.Lines.SaveToStream(ss);
und nicht
re.SaveToStream(ss);


Und warum machst du später nicht das umgekehrte, nämlich
re.LoadFromStream(ss);

[hde]

wenn überhaupt, dann: re.SaveRichText(Dest: TStream):Boolean
aber damit ist es noch nicht in mySQL
( aber DBRichEdit gibt's in Delphi )

[AlterMann]

Warum machst du
re.Lines.SaveToStream(ss);
und nicht
re.SaveToStream(ss);

Das war der entscheidende Hinweis

Und warum machst du später nicht das umgekehrte, nämlich
re.LoadFromStream(ss);

Das hatte ich versucht (zwar re.Lines.LoadFromStream(ss)), aber da ja das falsche gespeichert wurde, nützte das natürlich nix.

Außerdem kam auch noch

(Beliebter Fehler: nach dem Einlesen des DB-Feldes den Stream wieder an den Anfang zurücksetzen bevor er ans RichEdit übertragen wird)

zum tragen

So sieht das funktionierende Ding jetzt aus:

Code: Alles auswählen

function TForm20.RichText(re: TlzRichEdit): String;
var
   ss: TStringStream;
begin
   ss := TStringStream.Create ('');
   try
     re.SaveToStream(ss);
     Result := ss.DataString;
   finally
     ss.Free;
   end;
end;
 
procedure TForm20.Button2Click(Sender: TObject);
 
begin
  SQLQuery1.SQL.Text := 'INSERT INTO texte (titel, text) VALUES (:ttl,:txt)';
  SQLQuery1.Params.Clear;
  SQLQuery1.Params.CreateParam(ftString,'ttl', ptInput);
  SQLQuery1.Params.CreateParam(ftString,'txt', ptInput);
  SQLQuery1.ParamByName('ttl').AsString:= 'test';
  SQLQuery1.ParamByName('txt').AsString := Richtext(LZRichEdit1);
  SQLQuery1.ExecSQL; SQLTransaction1.Commit;
end;
 
procedure TForm20.Button3Click(Sender: TObject);
 
var ss: TStringStream;
 
begin
 SQLQuery1.SQL.Text := 'SELECT text from texte where titel = '+#39+'test'+#39;
 SQLQuery1.Open;
 ss := TStringStream.Create ('');
 try
   ss.WriteString(SQLQuery1.Fields[0].AsString);
   ss.Position:=0;
   lzRichEdit1.LoadFromStream(ss);
 finally
   ss.Free;
 end;
 SQLQuery1.Close;
end;
 

Vielen Dank euch allen
Christian