"Invalid Float" Fehler vorbeugen

[Modellman]

Ich habe ein kleines Rechenprogramm wo man in ein Eingabefenster eine Zahl eingeben muss.
Wenn man aber etwas anderes eingibt(Buchstaben, Alle Zeichen ausser ".") kommt die Meldung "Invalid Float".
Was muss man bei x eingeben, damit im Falle einer Flascheingabe ein Showmessagefenster kommt, dass sagt "Bitte eine Zahl eingeben"?
Hier der Code:

Code: Alles auswählen

procedure TForm1.BCalcClick(Sender: TObject);
var
   rRad, rOb, rVol :real;
const
  cPi = 3.14;
begin
 if [b](x)[/b] then
  begin
  rRad :=StrtoFloat(EInput.text);
  rOb :=4*cPi*rRad*rRad;
  rVol :=4/3*cPi*rRad*rRad*rRad;
  EOberflaeche.text :=FloattoStr(rOb);
  EVolumen.text :=FloattoStr(rVol);
end
 else
 begin
 Showmessage('Bitte eine Zahl eingeben!')
 end;
 end;

[theo]

http://www.swissdelphicenter.ch/de/showcode.php?id=1128

[Heinrich Wolf]

Code: Alles auswählen

 
ok := False;
try
  rRad :=StrtoFloat(EInput.text);
  ok := True;
except
  ShowMessage('Bitte eine Zahl eingeben');
end;
if ok then
  // weiterrechnen ist ok
// else
  // weiterrechnen macht keinen Sinn
 

Im Debugger wird immer noch 'invalid float' kommen, aber im exe nur noch 'Bitte eine Zahl eingeben'.

[gocher]

da würde ich eher TEdit erweitern

Code: Alles auswählen

unit Floatedit;
 
interface
 
uses
    StdCtrls, Classes, SysUtils;
 
type
  TFloatEdit = class(TEdit)
  private
    PreviousText: string;
  public
    constructor Create(AOwner: TComponent); override;
    procedure Change; override;
  end;
 
procedure Register;
 
implementation
 
procedure Register;
begin
  RegisterComponents('MyComps', [TFloatEdit]);
end;
 
constructor TFloatEdit.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  Text := '';
  PreviousText := '';
end;
  
procedure TFloatEdit.Change;
var
  iCode: integer;
  rValue: real;
begin
  Val(Text, rValue, iCode); 
  if (iCode>0) and (Text <> '-') and (Length(Text) > 0) then
    Text := PreviousText
  else
    PreviousText := Text;
  inherited Change;
end;
 
end.
 

[u-boot]

Wie wärs mit TFloatSpinEdit(.Value) ?

[diogenes]

Wie wärs mit TFloatSpinEdit(.Value) ?

Das ist natürlich die beste Idee, weil der User einfach nix falsch machen kann, als innerhalb des erlaubten Bereiches eine falsche Zahl zu wählen (wofür der Coder dann wirklich nix mehr kann ). Aber in manchen Fällen denke ich, daß man die Fehlererkennung vielleicht besser selbst macht und dem User zumindest einen Tip gibt, wo er's falsch gemacht hat. Z.B.: (ungetestet!)

Code: Alles auswählen

 
procedure QuaquaEditingDone( Sender: TObject);
 var
  Result: Float;
  ErrPos: Word= 0;
 begin
   repeat
     Val( Quaqua.Text, Result, ErrPos);
     if ErrPos <> 0
      then ShowMessage( Format( 'Das ist keine Gleitkommazahl, jedenfalls nicht ab Position %d!', [ErrPos]))
    until ErrPos = 0;
// Result weiterverarbeiten
  end;

[Schild]

Hallo,
ich hätte gerne eine Lösung die unabhängig für eine einzelne Abfrage funktioniert.
Über if then else.

so wie hier:

Code: Alles auswählen

procedure TForm1.Button1Click(Sender: TObject);
begin
  Edit1.Text := '123.222';
  if StrIsReal(Edit1.Text) then
    ShowMessage('Valid float number! Gültige Gleitkommazahl!');
end;

Vielen Dank.

[Michl]

Hallo und willkommen im Forum,

für Code nutze bitte den Highlighter "Freepascal/Lazarus", das liest sich besser:

Code: Alles auswählen

procedure TForm1.Button1Click(Sender: TObject);
var
  d: Double;
begin
  Edit1.Text := '123.222';
//  Edit1.Text := '123,222';  //Je nach DefaultFormatSettings.DecimalSeparator
  if TryStrToFloat(Edit1.Text, d) then
    ShowMessage('Valid float number! Gültige Gleitkommazahl!')
  else
    ShowMessage('Invalid float number! Ungültige Gleitkommazahl!')
end;

[wp_xyz]

Ich hasse Exceptions, und bei StrToFloat kann man diese mit TryStrToFloat vermeiden. Das kommt auch deinem letzten Posting sehr nahe. Da in deinem Beispiel der Zahlenstring einen Dezimalpunkt enthält, wird dies aber auf einem deutschen System nicht funktionieren - du musst noch die entsprechenden FormatSettings angeben:

Code: Alles auswählen

 
procedure TForm1.Button1Click(Sender: TObject);
var
  x: Double;
  fs: TFormatSettings;
begin
  fs := DefaultFormatSettings;
  fs.DecimalSeparator := '.';
  fs.ThousandSeparator := ' ';
  Edit1.Text := '123.222';
  if not TryStrToFloat(Edit1.Text, x, fs) then
    ShowMessage('Keine gültige Gleitkommazahl!');
end;
 
{ alternativ geht auch das "alte " val, aber nur mit Dezimalpunkt:
var
  x: double;
  code: Integer;
begin
  Edit1.Text := '123.222';
  val(Edit1.Text, x, code);
  if code <> 0 then
    ShowMessage('Keine gültige Gleitkommazahl');
end;
}

[Antrepolit]

TFloatSpinEdit benutzen. Vermeidet Fehler bevor sie entstehen und ist Locale-sicher.

[wp_xyz]

TFloatSpinEdit benutzen

Naja, manchmal sind die SpinButtons aber unerwünscht, z.B. wenn man Zahlen über einen großen Wertebereich eingeben muss und nicht weiß, wie das Increment am besten zu wählen ist, und leider kann man die SpinButtons nicht ausblenden.

[Mathias]

Wen die Funktion zwingend mit einem '.' sein muss, würde ich Val verwenden.

ZB. so:

Code: Alles auswählen

function StrToExtended(s: string): extended;
var
  e: integer;
begin
  Val(s, Result, e);
  if e <> 0 then begin
    ShowMessage('Fehler');
  end;
end;   

[Antrepolit]

TFloatSpinEdit benutzen

Naja, manchmal sind die SpinButtons aber unerwünscht, z.B. wenn man Zahlen über einen großen Wertebereich eingeben muss und nicht weiß, wie das Increment am besten zu wählen ist, und leider kann man die SpinButtons nicht ausblenden.

Man kann den Wert manuell eingeben und Fehleingaben werden im Vorfeld vermieden. Effektiver als alle IFs und TRY-EXCEPTS. Hier wird so oft das Rad neu erfunden mit

Code: Alles auswählen

if

und

Code: Alles auswählen

trystrtoint

und in jeder Variante finde ich auf einen Blick einen Fehler. Das ist also auch nicht die Lösung.