(Erledigt) onClick zur Laufzeit erstellen

[Levario]

Ich habe zu dem Thema bislang folgendes gefunden.
https://www.delphipraxis.net/46689-pane ... ellen.html

Leider funktioniert mein Code nicht, könnt ihr mir etwas auf die Sprünge helfen? Ich bekomme den Error
bei mypanel.OnClick:= mybuttonClick; und mytext.OnClick := mybuttonClick;
der Fehler lautet: Wrong numbers of parameters spezified for call to mybuttonClick.

Code: Alles auswählen

type

  { TMainForm }

  TMainForm = class(TForm)  
  ...
   procedure mybuttonClick(Sender : TObject);
  private
    procedure CreateNewButton;
  public
  end;       
  
  procedure TMainForm.CreateNewButton;
var
  mypanel : TPanel;
  myimage : TImage;
  mytext : TLabel;
  stri : string;
begin

  stri := IntToStr(inti);

 mypanel:=TPanel.Create(Self);
 mypanel.parent := MainForm;
 mypanel.top := 93;
 mypanel.height := 32;
 mypanel.Width:= 160;
 mypanel.name := 'MyPanel' + stri;
 mypanel.caption := '';
 mypanel.color := TColor($00333333);
 mypanel.OnClick:= mybuttonClick;

 mytext := TLabel.Create(Self);
 mytext.parent := mypanel;
 mytext.top := 5;
 mytext.left := 39;
 mytext.Font.color := clWhite;
 mytext.Font.Name := 'Segoe UI';
 mytext.Font.Size := 12;
 mytext.Font.Style:= [fsBold];
 mytext.caption := 'MyWebseite';
 mytext.name := 'MyText' + stri;
 mytext.OnClick := mybuttonClick;
end;

procedure TMainForm.mybuttonClick(Sender : TObject);
begin
 OpenURL('https://www.mywebsite.de');
end;
end.                                  

[wennerer]

Guten Morgen,
du musst ein @ davor setzen.

Sieht dann so aus:

Code: Alles auswählen

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  { TMainForm }

  TMainForm = class(TForm)
    procedure FormCreate(Sender : TObject);
    procedure MyOnClick(Sender : TObject);
  private
    MyButton : TButton;
  public

  end;

var
  MainForm : TMainForm;

implementation

{$R *.lfm}

{ TMainForm }


procedure TMainForm.FormCreate(Sender : TObject);
begin
 MyButton     := TButton.Create(self);
 MyButton.Parent := self;
 MyButton.SetBounds(20,20,150,25);
 MyButton.Caption := 'MyOnClick';
 MyButton.OnClick := @ MyOnClick;
end;

procedure TMainForm.MyOnClick(Sender : TObject);
begin
  showmessage('Du hast geklickt!');
end;

end.

Viele Grüße
Bernd

[theo]

Ich habe zu dem Thema bislang folgendes gefunden.
https://www.delphipraxis.net/46689-pane ... ellen.html

Wenn du Delphi Code direkt übernehmen willst, geht auch {$MODE DELPHI}
https://www.freepascal.org/docs-html/prog/progse74.html

[Levario]

Wow, guten morgen,

schnelle Hilfe vielen Dank die Software läuft.

Gruß Levi

[Mathias]

Wen du folgendes schreibst und anschliessend [Ctrl + Shift + c] drückst, macht es dir alles automatisch.

Code: Alles auswählen

OnClick:=

[theo]

Wen du folgendes schreibst und anschliessend [Ctrl + Shift + c] drückst, macht es dir alles automatisch.

Code: Alles auswählen

OnClick:=

Eben nicht! Er macht kein @.
Oder in welcher Version/Einstellung ist das so?

[Mathias]

Wen du folgendes schreibst und anschliessend [Ctrl + Shift + c] drückst, macht es dir alles automatisch.

Code: Alles auswählen

OnClick:=

Eben nicht! Er macht kein @.
Oder in welcher Version/Einstellung ist das so?

In der aktuellen Stable ohne irgendwelchen Einstellungen.
Und dies bei einem neuen leeren Project.

Code: Alles auswählen

procedure TForm1.FormCreate(Sender: TObject);
begin
  OnClick:=  // Hier : [Ctrl + Shift + c] 
end;