UniqueInstance Richtig an / Abschalten [gelöst]

[corpsman]

Hallo Zusammen,

ich habe eine Anwendung geschrieben, welche "normalerweise" nicht mehrfach gestartet werden soll => Klarer Fall für UniqueInstance.
Wenn ich nun aber meine Anwendung Teste, dann benötige ich doch mehrere Instancen.
Die Idee war nun das ganze mittels eines Kommandozeilen Parameter zu steuern:

Code: Alles auswählen

Procedure TForm1.UniqueInstance1OtherInstance(Sender: TObject;
  ParamCount: Integer; Const Parameters: Array Of String);
Begin
  BringToFront;
  showmessage('Other Instance detected');
End;

Procedure TForm1.FormCreate(Sender: TObject);
Var
  i: Integer;
Begin
  label1.caption := 'Disabled';
  For i := 1 To ParamCount Do Begin
    If ParamStr(i) = '-d' Then Begin
      UniqueInstance1.Enabled := true;
      label1.caption := 'Enabled';
    End;
  End;
End;

Das Problem ist aber, dass das nicht geht, wenn ich im OE Enabled auf True stelle ist es immer an, wenn ich es aus mache immer aus, es scheint keine Möglichkeit zu geben das zur "Create" zeit zu entscheiden, oder übersehe ich hier etwas ?

[corpsman]

Ahh, wenn man es in der .lpr Datei macht, dann scheint es zu gehen:

Code: Alles auswählen

Program project1;

{$MODE objfpc}{$H+}

Uses
{$IFDEF UNIX}
  cthreads,
{$ENDIF}
{$IFDEF HASAMIGA}
  athreads,
{$ENDIF}
  Interfaces, // this includes the LCL widgetset
  Forms, unit1
  { you can add units after this }
  , UniqueInstanceRaw, UniqueInstance;

{$R *.res}

Var
  CheckInstance: Boolean;
  ui: TUniqueInstance;
  i: Integer;

Begin
  CheckInstance := true;
  For i := 1 To ParamCount Do Begin
    If ParamStr(i) = '-d' Then Begin
      CheckInstance := false;
    End;
  End;
  If CheckInstance Then Begin
    If InstanceRunning('Blubber_Blub') Then Begin
      halt;
    End;
  End;
  RequireDerivedFormResource := True;
  Application.Scaled := True;
  Application.Initialize;
  Application.CreateForm(TForm1, Form1);
  If CheckInstance Then Begin
    ui := TUniqueInstance.Create(form1);
    ui.Name := 'UniqueInstance1';
    ui.Identifier := 'Blubber_Blub';
    ui.Enabled := true;
    ui.OnOtherInstance := @form1.UniqueInstance1OtherInstance;
  End;
  Application.Run;
End.

Die Frage ist nun, wie sauber ist das ?

[fliegermichl]

Ich vermute mal, daß FormCreate zu früh ist. Es werden die Eigenschaften des Formulares und seiner Komponenten erst später geladen und somit dein Enabled/disabled wieder übergebügelt.

[corpsman]

Naja in dem Beispiel das funktioniert erstelle ich alles noch deutlich for Form.Create, also meinst du eher zu Spät ...

[theo]

Die Frage ist nun, wie sauber ist das ?

Was verstehst du unter "sauber"?
Wenn's funktioniert wird es wohl richtig sein.

Ein bisschen viele unnötige begin..end hast du noch drin.

Den ganzen Block:

Code: Alles auswählen

 For i := 1 To ParamCount Do Begin
    If ParamStr(i) = '-d' Then Begin
      CheckInstance := false;
    End;
  End;
  If CheckInstance Then Begin
    If InstanceRunning('Blubber_Blub') Then Begin
      halt;
    End;
  End;

könnte man verlustlos auch so schreiben:

Code: Alles auswählen

 For i := 1 To ParamCount Do 
   If ParamStr(i) = '-d' then CheckInstance := false;
If CheckInstance and InstanceRunning('Blubber_Blub') then halt;

Wenn du bei CheckInstance := false; ein begin...end möchtest, dann nutze es um mit "break" aus der Schleife zu springen.

[corpsman]

*g*,
es ging mir nicht um Codierrichtlinen, den die sind ja wie Religion, mir ging es eher um "sachgemäße" Benutzung. Nur weil etwas funktioniert, heist es nicht dass es Richtig ist.

Aber Danke, setze es auf gelöst.

[theo]

Nur weil etwas funktioniert, heist es nicht dass es Richtig ist.

Bei Multithreading und Unicode gebe ich dir recht!
Aber das hier ist ja recht überschaubar. Teste es und gut.

[fliegermichl]

Naja in dem Beispiel das funktioniert erstelle ich alles noch deutlich for Form.Create, also meinst du eher zu Spät ...

Aehm nö. In der lpr wird Application.CreateForm(TForm1, Form1) aufgerufen und erst danach die Instanz der TUniqueInstance erstellt.

[corpsman]

Ich meinte den Aufruf von:

InstanceRunning

Der erstellt im Hintergrund den Server