[ERLEDIGT] fcl-pdf (fpPDF) --> TChart nach PDF exportieren

[Zvoni]

Hallo zusammen,

Lazarus=4.3 64bit-Windows
FPC = 3.2.3 - 64Bit Windows

Target = Windows64

Ich habe ein TChart, welches ich nach PDF exportieren soll

Habe wie folgt

Code: Alles auswählen

function ExportChartToPDF(AChart: TChart; AFileName: String): Boolean;
var
  Bitmap: TJpegImage;
  PDFDoc: TPDFDocument;
  Section: TPDFSection;
  Page: TPDFPage;
  ImgIndex: Integer;
  b:boolean;
  m:TMemoryStream;
begin
  Result:=True;
  b:=True;
  Bitmap := TJpegImage.Create;
  try
    Bitmap.SetSize(AChart.Width, AChart.Height);  //Grösse anpassen
    AChart.PaintTo(Bitmap.Canvas, 0, 0);  //Zeichne das Chart ins JPEG
    m:=TMemoryStream.Create;
    Bitmap.SaveToStream(m);  //Wirf das Bitmap in einen Stream
    m.Position:=0;

    PDFDoc := TPDFDocument.Create(nil);
    try
      PDFDoc.StartDocument;
      Section := PDFDoc.Sections.AddSection;
      Page := TPDFPage.Create(PDFDoc);
      Page.Orientation:=ppoLandscape;
      Section.AddPage(Page);

      ImgIndex := PDFDoc.Images.AddJPEGStream(m, Bitmap.Width, Bitmap.Height);

      Page.DrawImage(10, 10, AChart.Width, AChart.Height, ImgIndex);
      ShowMessage('Sections-Count='+PDFDoc.Sections.Count.ToString);
      ShowMEssage('Page-Count='+PDFDoc.Sections[0].PageCount.ToString);
      // 5. Save the PDF file
      PDFDoc.SaveToFile(AFileName);
    Except
      On E:Exception Do b:=False;
    end;
  finally
    m.Free;
    PDFDoc.Free;
    Bitmap.Free;
  end;
  Result:=Result And b;
end;          

Die zwei ShowMessages zeigen korrekt jeweils 1 an (Section und Pages)
Beim SaveTofile knallts mit EListError Invalid Page Index (=0)

Kenn mich mit PDF und dem ganzen Kram überhaupt nicht aus.
Wo sitzt der Fehler?

[Zvoni]

OK. Zumindest der Teil mit der Exception ist erledigt.

Vielen Dank an Nummer8 für den Beitrag hier:
viewtopic.php?t=17780

Hab die Erzeugung der Page geändert, und dann gings.
Jetzt gehts nur noch darum, wieso er die Orientation nicht akzeptiert, plus die Skalierung runter auf DIN A4 quer

[Zvoni]

OK, Orientation ist erledigt, aber das PDF ist "leer" also keine "Grafik" des Charts.

Scheint was mit dem Stream zu sein

[paweld]

Ein vollständiges Beispiel (basierend auf dem Tachart Basic-Demo) finden Sie im Anhang

Code: Alles auswählen

function TForm1.ExportChartToPDF(AChart: TChart; AFileName: String): Boolean;
var
  jpg: TJpegImage;
  pdf: TPDFDocument;
  pdfs: TPDFSection;
  pdfp: TPDFPage;
  idx, m, w, h, px, py: Integer;
  scale: Double;
  ms: TMemoryStream;
begin
  Result := False;
  jpg := TJpegImage.Create;
  ms := TMemoryStream.Create;
  pdf := TPDFDocument.Create(nil);
  try
    jpg.SetSize(AChart.Width, AChart.Height);
    AChart.PaintTo(jpg.Canvas, 0, 0);
    jpg.SaveToStream(ms);
    ms.Position := 0;
    pdf.StartDocument;
    pdfs := pdf.Sections.AddSection;
    pdfp := pdf.Pages.AddPage;
    pdfp.Orientation := ppoLandscape;
    pdfp.UnitOfMeasure := uomPixels;
    pdfp.PaperType := ptA4;
    pdfs.AddPage(pdfp);

    idx := pdf.Images.AddJPEGStream(ms, jpg.Width, jpg.Height);

    //10 mm Rand in px
    m := trunc(mmToPDF(10));
    //Verkleinere das Bild auf der Seite, falls nötig
    scale := jpg.Width / (pdfp.Paper.W - 2 * m);
    if (jpg.Height / (pdfp.Paper.H - 2 * m)) > scale then
      scale := jpg.Height / (pdfp.Paper.H - 2 * m);
    if scale < 1 then
      scale := 1;
    w := trunc(jpg.Width / scale);
    h := trunc(jpg.Height / scale);
    //auf der Seite zentrieren
    px := (pdfp.Paper.W - w) div 2;
    py := (pdfp.Paper.H - h) div 2;

    pdfp.DrawImage(px, py, w, h, idx);
    pdf.SaveToFile(AFileName);
    Result := True;
  except
    on E: Exception do
      raise Exception.Create(E.Message);
  end;
  pdf.Free;
  ms.Free;
  jpg.Free;
end;  

[Zvoni]

Pawel,

vielen, vielen Dank!!
Funktioniert perfekt!!

[af0815]

Das Beispiel von Pawel ist super und kann als Vorlage dienen für alles was man als Image exportieren kann.

Danke für das Beispiel.

[wp_xyz]

paweld, wenn du nichts dagegen hast, würde ich deinen Code gerne in das Beispiel-Projekt "save" von TAChart aufnehmen.

[paweld]

@wp Natürlich habe ich nichts dagegen. Eigentlich sollte ich diese Frage stellen, da ich deinen Code verwendet habe, um dieses Beispiel zu erstellen

[wp_xyz]

OK, ist mit in der Tüte.