[Solved] array of record Frage

[sstvmaster]

Hi, ich wollte so was machen.

Code: Alles auswählen

type
  TStation = record
    Call: string;
    Location: string;
    OP: string;
    ST: byte; // start time
  end;

var
  VStations: array[0..17] of TStation = (
    ('4u1un', 'United Nations', 'UNRC', 0 ),
    ('ve8at', 'Canada', 'RAC/NARC', 10 ),
    ('w6wx', 'United States', 'NCDXF', 20 ),
    ('kh6rs', 'Hawaii', 'MARC', 30 ),
    ('zl6b', 'New Zealand', 'NZART', 40 ),
    ('vk6rbp', 'Australia', 'WIA', 50 ),
    ('ja2igy', 'Japan', 'JARL', 60 ),
    ('rr9o', 'Russia', 'SRR', 70 ),
    ('vr2b', 'Hong Kong', 'HARTS', 80 ),
    ('4s7b', 'Sri Lanka', 'RSSL', 90 ),
    ('zs6dn', 'South Africa', 'ZS6DN', 100 ),
    ('5z4b', 'Kenya', 'ARSK', 110 ),
    ('4x6tu', 'Israel', 'IARC', 120 ),
    ('oh2b', 'Finland', 'SRAL', 130 ),
    ('cs3b', 'Madeira', 'ARRM', 140 ),
    ('lu4aa', 'Argentina', 'RCA', 150 ),
    ('oa4b', 'Peru', 'RCP', 160 ),
    ('yv5b', 'Venezuela', 'RCV', 170 )
  );

geht natürlich nicht.

bacons.lpr(16,6) Fatal: Syntax error, "identifier" expected but "const string" found

das geht aber:

Code: Alles auswählen

VStations: array[0..17] of TStation = (
    (Call: '4u1un'; Location: 'United Nations'; OP: 'UNRC'; ST: 0 ),
    ...

Warum muss man den Identifier immer mit schreiben?
Geht das auch anders?

[Winni]

Hi!

Beim array of record müssen immer die einzelnen Felder identifiziert werden.
Finde ich auch umständlich.
Selbst bei solch einfachen Sachen wie einem array of TPoint musst Du
x und y identifizieren.

Das was schon in Turbo-Zeiten so.
Ohne geht das nur beim einem Array of SimpleType:

Farben : array[0..2] of string = ('rot','gruen','blau');

Warum das so ist: Bitte frag die Compiler-Konstrukteure.
Hier ist fast täglich einer unterwegs.

Winni

[Socke]

Warum das so ist: Bitte frag die Compiler-Konstrukteure.

Füge deinem Record ein Feld hinzu und du weißt warum

[PascalDragon]

Warum das so ist: Bitte frag die Compiler-Konstrukteure.

Füge deinem Record ein Feld hinzu und du weißt warum

Genau. Das ist auch der Grund, warum neuere C- und C++-Standards das auch hinzugefügt haben (wobei GCC das schon lange unterstützt). Die verbliebenen Felder werden nämlich auf "0" initialisiert (und der Rest verschiebt sich einfach) und das kann dann unangenehme Seiteneffekte haben und schwer zu debuggen sein (und ja, mich hat sowas schon mal betroffen).

Es mag also mehr Schreibaufwand sein, aber es zeichnet sich durch Sicherheit aus - wie vieles bei Pascal.

[fliegermichl]

Es mag also mehr Schreibaufwand sein, aber es zeichnet sich durch Sicherheit aus - wie vieles bei Pascal.

Hm das mag schon sein. Ich denke doch aber, daß der Compiler rausbekommen kann, wieviele Felder der Record hat und von welchem Typ die sind.
Bei Varianten Records gebe ich dir Recht aber bei so einfachen?.

[Sieben]

Das ist doch gerade der Witz an dieser Sprache, dass hier keine Ratespielchen veranstaltet werden, was der Programmierer wahrscheinlich oder vielleicht gemeint haben könnte, sondern möglichst strikt nur das gemacht wird, was er explizit angewiesen hat. Das ist für meinen Geschmack ohnehin schon ziemlich verwässert worden.

Mit der anderen Variante spart man sich vielleicht und wie schon gesagt ein bisschen Schreibarbeit, hat dann aber die lustigen Überraschungen zur Laufzeit.

[Mathias]

Wen ihr mal eine anständige Konstante sehen wollt, habe ich hier etwas.

https://github.com/sechshelme/Lazarus-E ... _const.pas

[af0815]

Wenn die erste Zeile nicht wäre, so wäre es echt beeindruckend. SCNR

[fliegermichl]

[Mathias]

Wenn die erste Zeile nicht wäre, so wäre es echt beeindruckend. SCNR

Die einfachste Variante, wen man keine INI Dateien will.

[PascalDragon]

Es mag also mehr Schreibaufwand sein, aber es zeichnet sich durch Sicherheit aus - wie vieles bei Pascal.

Hm das mag schon sein. Ich denke doch aber, daß der Compiler rausbekommen kann, wieviele Felder der Record hat und von welchem Typ die sind.
Bei Varianten Records gebe ich dir Recht aber bei so einfachen?.

Es braucht keine Varianten Records. Nimm das folgende, recht dumme Beispiel:

Code: Alles auswählen

type
  TPerson = record
    Name: String;
    City: String;
  end;
  
 const
   Persons: array of TPerson = (
     ( Name: 'Max Mustermann' ; City: 'Musterstadt'),
     ( Name: 'Erika Musterfrau'; City: 'Musterstadt')
   ); 

Nun nimm mal an du trennst Name in FirstName und LastName auf, vergisst aber die Konstante anzupassen (vielleicht weil du abgelenkt wurdest und es dann vergessen hast - passiert mir oft genug - oder vergessen hast, dass die Konstante überhaupt existiert - kann in größeren Projekten vorkommen). Mit den benannten Feldern wird der Compiler meckern bzw. zumindest warnen (wenn sich keine Feldnamen geändert haben), hättest du aber Record Konstanten ohne Feldnamen würde das passieren:

Code: Alles auswählen

type
  TPerson = record
    FirstName: String;
    LastName: String;
    City: String;
  end;
  
const
   Persons: array of TPerson = (
     ( 'Max Mustermann' ; 'Musterstadt'),
     ( 'Erika Musterfrau'; 'Musterstadt')
   ); 

Nun sind in der Konstante die Felder FirstName und LastName gefüllt, aber City ist leer. Gut, sowas dürfte recht leicht auffallen, aber habe hier mal zum Beispiel numerische Felder, wo es nicht so leicht ist zu sagen, ob die Zahl nun so richtig ist oder nicht.

Pascal geht hier eben einfach den Weg, der dir am wenigsten ins Knie schießt.

[sstvmaster]

Hallo Leute,

vielen Dank für eure Erklärungen und Beispiele, warum, wieso, weshalb das so gemacht werden muss.

Das hat mir sehr geholfen.

LG Maik

[sstvmaster]

Nachtrag: wäre das nicht auch was für das Wiki?

Array of record gibt es nicht, oder ich bin blind.

[wp_xyz]

Falls du dich auf das "Persons: array of TPerson" von PascalDragon beziehst: Das gibt es sein FPC 3.2 (https://wiki.freepascal.org/FPC_New_Fea ... ialization).

Folgender Code compiliert mit 3.2, aber nicht mit 3.0.4:

Code: Alles auswählen

program Project1;

type
  TPerson = record
    Name: String;
    City: String;
  end;

 const
   Persons: array of TPerson = (
     ( Name: 'Max Mustermann' ; City: 'Musterstadt'),
     ( Name: 'Erika Musterfrau'; City: 'Musterstadt')
   );

var
  p: TPerson;
begin
  for p in Persons do
    WriteLn(p.Name, ' in ', p.City);

  ReadLn;
end.  

[Socke]

Nachtrag: wäre das nicht auch was für das Wiki?

Ich habe es mal hier ergänzt: https://wiki.freepascal.org/Record#Constant_record