Problem einbetten einer Progressbar in eine StatusBar

[Linkat]

Hallo,
ich möchte eine Progressbar ín eine Statusbar einbetten.

Warum erscheint die Progressbar nicht.

Code: Alles auswählen

unit StatusProgu;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ComCtrls, StdCtrls,
  Buttons;

type

  { TForm1 }

  TForm1 = class(TForm)
    BitBtn1: TBitBtn;
    Button1: TButton;
    StatusBar1: TStatusBar;
    procedure Button1Click(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure StatusBar1DrawPanel(StatusBar: TStatusBar; Panel: TStatusPanel;
      const Rect: TRect);
  private
    ProgBar                      :TProgressBar;
  public

  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  ProgBar:=TProgressBar.Create(Self);
  ProgBar.Anchors:=[];
  ProgBar.Min:=0;
  ProgBar.Max:=100;
  ProgBar.Position:=0;
  ProgBar.Height:=15;
  ProgBar.Width:=60;
  ProgBar.Parent:=StatusBar1;
  StatusBar1.Panels[0].Style:=psOwnerDraw;
  ProgBar.Visible:=True;
  ProgBar.Enabled:=True;
  StatusBar1.Invalidate;
end;

procedure TForm1.Button1Click(Sender: TObject);
var i           :Integer;
begin
  for i:=0 to 100 do begin
    Caption:=i.ToString;
    Application.ProcessMessages;
    ProgBar.Position:=i;
    Sleep(10);
  end;
end;

procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  ProgBar.Free;
end;

procedure TForm1.StatusBar1DrawPanel(StatusBar: TStatusBar;
  Panel: TStatusPanel; const Rect: TRect);
begin
  if (Panel=StatusBar1.Panels[0]) then ProgBar.BoundsRect:=Rect;
end;

end.

hat jemand eine Idee?

Vielen Dank.

Gruß, Linkat

[wp_xyz]

Bei mir (Win-11) hat sich die Progressbar gezeigt. Ich habe trotzdem deinen Code wie folgt vereinfacht:

Code: Alles auswählen

procedure TForm1.FormCreate(Sender: TObject);
begin
  ProgBar:=TProgressBar.Create(Self);
  ProgBar.Min:=0;
  ProgBar.Max:=100;
  ProgBar.Position:=0;
  ProgBar.Parent:=StatusBar1;
  ProgBar.Visible:=False;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  i: Integer;
begin
  ProgBar.SetBounds(0, 0, Statusbar1.Width-1, Statusbar1.Height-1);
  ProgBar.Show;
  for i:=0 to 100 do begin
    Caption:=i.ToString;
    Application.ProcessMessages;
    ProgBar.Position:=i;
    Sleep(10);
  end;
end; 

Grund-Idee:
- Parent der Progressbar auf die Statusbar setzen
- Zunächst Progressbar verstecken (ProgBar.Visible := false, oder ProgBar.Hide)
- Wenn der zu überwachende Prozess startet, Progressbar anzeigen (ProgBar.Show) und in Größe der Größe der Statusbar anpassen
- Am Ende Progressbar ggfs wieder verstecken (aber Achtung bei Windows: hier wird wegen der Animation die Progressbar evtl schon ausgeblendet, bevor sie ganz gefüllt ist.)
- Ein Custom-Draw des Status-Panels ist nicht erforderlich.

Ach ja noch: Da du die ProgressBar mit Owner Self (also dem Formular) erzeugst, musst du keinen Code mehr schreiben, um sie wieder freizugeben. Darum kümmert sich der Owner automatisch.

[Zvoni]

Müsste nicht das Panel der StatusBar der Parent/Owner sein?
Würde doch deutlich mehr Sinn ergeben

[af0815]

Müsste nicht das Panel der StatusBar der Parent/Owner sein?
Würde doch deutlich mehr Sinn ergeben

Das hängt IMHO davon ab, ob die Statusbar im "simple Mode" oder mit Panels konfiguriert ist.

[Linkat]

Vielen Dank @wp_xyz und Zvoni für Hinweise und Tipps.

Aber es funktioniert leider nicht.

Vor über 10 Jahren (in der Firma) hatte ich eine Progressbar In eine Statusbar in einem Windows-Programm eingearbeitet. Aber genau diese Technik funktioniert nicht auf meinem Linux Mint.

Da dies eh nur ein optischer Effekt ist, werde ich also vorerst die Progressbar am unteren Rand anordnen und mein eigentliches Programm weiter entwickeln.

Gruß,
Linkat

[wp_xyz]

Aber genau diese Technik funktioniert nicht auf meinem Linux Mint.

Dass du auf Mint bist, hättest du gleich im ersten Beitrag sagen können, dann hätte man sich diesen Spezialfall gleich von Anfang an vornehmen können.

Aber egal: Ich habe nun mein Testprogramm auf Mint laufen lassen, und - ja - da erscheint die Progressbar nicht, zumindest nicht unter gtk2, unter qt5 funktioniert alles wie gewünscht. Auch der Versuch, unter gtk2 auf die Progressbar komplett zu verzichten und stattdessen einfach im StatusPanel ein größer werdendes Rechteck zu zeichnen, schlägt fehlt, weil das OnDrawPanel-Ereignis offenbar nicht aufgerufen wird. In diesem Fall würde ich die Progressbar im Parent Formular belassen und mit Align=alBottom an den unteren Rand des Formulars setzen. Dann wenn die zu verfolgenden Prozess läuft, würde ich die Progressbar auf sichtbar schalten und die Statusbar auf unsichtbar.

Code: Alles auswählen

procedure TForm1.Button4Click(Sender: TObject);
var
  i: Integer;
begin
  ProgBar.Parent := self;
  ProgBar.Align := alBottom;
  ProgBar.Show;
  Statusbar1.Hide;
  for i:=0 to 100 do begin
    Caption:=i.ToString;
    ProgBar.Position:=i;
    Application.ProcessMessages;
    Sleep(10);
  end;
  ProgBar.Hide;
end; 

[wp_xyz]

Müsste nicht das Panel der StatusBar der Parent/Owner sein?
Würde doch deutlich mehr Sinn ergeben

TStatusPanel ist kein TWinControl, kann also nicht als Parent der Progressbar fungieren. Ob es der Owner sein soll, wäre abzuwägen. Denn wenn man das Panel löscht, würde dann auch die Progressbar gelöscht - fatal, wenn man die vielleicht auch noch für etwas anderes einsetzen will.

[theo]

Aber genau diese Technik funktioniert nicht auf meinem Linux Mint.

Dass du auf Mint bist, hättest du gleich im ersten Beitrag sagen können, dann hätte man sich diesen Spezialfall gleich von Anfang an vornehmen können.

Ich würde bevorzugen, wenn die Leute dazuschreiben würden, welches Widgetset sie verwenden (GTK2, GTK3, Qt4/5/6...).
Die Distribution finde ich in diesem Zusammenhang erst einmal nicht entscheidend.
Und ja, wenn man "komisches Zeug" macht, sollte man das Widgetset immer angeben, weil "komisches Zeug" auf manchen Umgebungen läuft und auf anderen vielleicht ungetestet oder unmöglich ist.

[Ally]

Hallo Linkat,

anbei noch ein ganz anderer Lösungsansatz.
Ein Panel mit dem Ankereditor am unteren Fensterrand verankern, darauf kann man dann was auch immer platzieren und mit dem Ankereditor ausrichten.

Gruß Roland

[Zvoni]

Vielleicht hier?
https://forum.lazarus.freepascal.org/in ... 09.15.html
User hat laut Signatur auch Mint

Oder hier: https://forum.lazarus.freepascal.org/in ... ic=35831.0
Hauptproblem scheinen die Anchors zu sein

[Linkat]

Linux Mint steht zwar in der Signatur aber nicht GTK2. Aber besser ist, wenn man genauere Angaben macht.

Vielen Dank an alle, die sich hier beteiligt haben. Ich werde wie oben angedeutet und von WP und Ally in ähnlicher Form gelöst, eine Lösung ohne StatusBar anwenden.

Ich schreibe in den Header nicht [gelöst], da ja eine andere Lösung genutzt wird. Aber vielleicht gibt es ja später einmal ein Lösungsweg.

Viele Grüße,
Linkat

[Niesi]

.

[Niesi]

Hallo,
ich möchte eine Progressbar ín eine Statusbar einbetten.

Warum erscheint die Progressbar nicht.

...

hat jemand eine Idee?

Vielen Dank.

Gruß, Linkat

Schau mal bitte, vielleicht kannst Du damit leben - ist ein wenig aufwändiger, aber die Optik dürfte stimmen (Ich hab die StatusBar1 weiß eingefärbt, damit sie besser erkennbar ist) ...


StatusProgII.7z


Bildschirmfoto vom 2024-11-08 19-21-04.png

Bildschirmfoto vom 2024-11-08 19-21-10.png
[/quote]

[Niesi]

.

[Linkat]

@Niesi
Vielen Dank für dein Beispiel.
Aber in dem Programm ist die ProgressBar nicht in der Statusbar eingebettet. Es fehlt die Parent Zuweisung und die DrawPanel-Prozedur ist wirkungslos. Es ist letztendlich wie bei dem Vorschlag von wp_xyz ein ein- und ausschalten der Progressbar und Statusbar.
So ähnlich habe ich das jetzt auch in mein Programm eingebaut.

Gruß, Linkat